Deploy Google Chrome Package with SCCM 2012

In this tutorial we will explain how to Deploy Google Chrome with package in the Configuration Manager 2012. The deployment is based on script silently installation. We will get “msi” version 41.0.2272.7 to demonstrate. The package will disable automatic update check. The entire process will be a silent install – your end-user won’t notice a thing!

The following tasks included:

Install or Deploy Google Chrome
Create logs for status of installation
Disable Update Checking / Auto update

Note: The script can run with and without SCCM 2012.

Preparation.

The .MSI file can be downloaded for both at :

http://www.google.co.uk/intl/en/chrome/business/browser/admin/

https://www.google.com/chrome/browser/desktop/index.html?msi=true

Step 1: Create package for deploy Google Chrome on your PC.

Create a folder with name “ Deploy Google Chrome Package ”. Copy the .msi downloaded for Google Chrome. Inside the folder, create a text file called install.cmd and copy in the following command lines:


@echo off
@rem DESCRIPTION: Google Chrome Deployment 41.0.2272.7
@echo off
@Rem === Variables_declaration-START ===============================
Set AppliName=Google Chrome
Set PackageName=Google_Chrome_41.0.2272.7
Set PackageNameScript=Google_Chrome_41.0.2272.7
Set Version=41.0.2272.7
Set LogfilepathCmd=C:\Log_Test\%PackageName%_Ins_Script.txt
Set MSIFile=googlechromestandaloneenterprise.msi
Set master=master_preferences.txt
@Rem === Variables_declaration-END =================================
cls
if not exist "C:\Log_Test\" md "C:\Log_Test\"
@echo --------------------------------------------------------------------- >>%LogfilepathCmd%
@echo %AppliName% install script >>%LogfilepathCmd%
@echo This logs doesn't include the %AppliName% install logs. >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
FOR /F  %%I IN ('DATE /T') DO FOR /F  %%J IN ('Time /T') DO echo %%I %%J       >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
Rem ================================
Rem ========= Installation       ===========
Rem ================================
Rem Installation
@echo Installation  of %AppliName% >>%LogfilepathCmd%
start /wait msiexec /i "%~dp0%MSIFile%" /qn /l* "C:\Log_Test\%PackageName%_insta_Script.txt"
set errorcode=%errorlevel%
If "%errorCode%"=="3010" (Set errorcode=0
@echo errorCode=3010, A restart is required to complet the install >>%LogfilepathCmd%
)
If "%errorCode%"=="1641" (Set errorcode=0
@echo errorCode=1641, The installer has initiated a restart >>%LogfilepathCmd%
)
 
@echo Return Code of %AppliName% installation = %errorcode% >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
Rem ===============================================
Rem ========= Setting                                                            ===========
Rem ================================================
@echo Set the parameter file >>%LogfilepathCmd%
@XCOPY "%~dp0master_preferences.txt" "C:\Program Files\Google\Chrome\Application\" /E /C /Q /R /Y >>%LogfilepathCmd%
@XCOPY "%~dp0master_preferences.txt" "C:\Program Files (x86)\Google\Chrome\Application\" /E /C /Q /R /Y >>%LogfilepathCmd%
reg add HKLM\Software\Policies\Google\Update /f /v AutoUpdateCheckPeriodMinutes /d 0 >>%LogfilepathCmd%
sc stop gupdate >>%LogfilepathCmd%
sc config gupdate start= disabled >>%LogfilepathCmd%
 
Rem ================================================
Rem ========= End of Script       ===========
Rem ================================================
:END
FOR /F  %%I IN ('DATE /T') DO FOR /F  %%J IN ('Time /T') DO echo %%I %%J       >>%LogfilepathCmd%
@echo end of script >>%LogfilepathCmd%
@echo Error code script = %errorcode% >>%LogfilepathCmd%
@echo --------------------------------------------------------------------- >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
@echo. >>%LogfilepathCmd%
exit %errorcode%

Note: Rename the google chrome msi “googlechromestandaloneenterprise.msi”

Create a text file called master_preferences.txt and copy in the following command lines :


{
"homepage" : "http://www.google.com",
"homepage_is_newtabpage" : false,
"browser" : {
"show_home_button" : true,
"check_default_browser" : false,
"window_placement": {
"bottom": 1000,
"left": 10,
"maximized": false,
"right": 904,
"top": 10,
"work_area_bottom": 1010,
"work_area_left": 0,
"work_area_right": 1680,
"work_area_top": 0
}
},
"bookmark_bar" : {
"show_on_all_tabs" : true
},
"distribution" : {
"skip_first_run_ui" : true,
"show_welcome_page" : false,
"import_search_engine" : false,
"import_history" : false,
"create_all_shortcuts" : true,
"do_not_launch_chrome" : true,
"make_chrome_default" : false
}
}

Step 2: Create package on SCCM 2012 for Deploy Google Chrome.

Note: If you want to install the package without deployment, just right-click on the install.cmd and run as administrator. Check logs for the perform of the installation.

To create the package follow the instruction in the previous post :

http://www.get-itsolutions.com/deploy-adobe-flash-player-17-package-with-sccm/

The package folder looks like: